当前位置:首页 >> 电子/电路 >>

51单片机 交通灯 汇编语言编写


;倒计时交通灯




;四位共阳数码管

;P0 接段码

;P2.0123 接位码




;P3 接红绿黄灯




NB_R EQU P3.0

NB_Y EQU P3.1

NB_G EQU P3.2




DX_R EQU P3.3

DX_Y EQU P3.4

DX_G EQU P3.5




;-------------------------------------------

ORG 0000H

JMP MAIN

ORG 000BH ;T0中断的入口地址

MOV TL0, #0B0H

MOV TH0, #3CH ;50ms中断一次

DJNZ R2, EXIT_T0

MOV R2, #20 ;定时1s

DEC R3 ;倒计时

DEC R4 ;倒计时

EXIT_T0:

RETI

;***************************************

MAIN:

MOV TMOD, #01H

MOV TH0, #3CH ;定时50ms

MOV TL0, #0B0H

MOV R2, #20 ;定时1s

SETB TR0

SETB ET0

SETB EA

MOV SP, #60H

;***************************************

N_B: ;南北

MOV P3, #0 ;关闭全部红绿灯

SETB NB_G

SETB DX_R

MOV R3, #20 ;南北通行时间

MOV R4, #25

NB_W1:

CJNE R3, #0, NB_DISP

MOV R3, #5 ;南北黄灯时间

SJMP N_B_Y

NB_DISP:

CALL DISPLAY

SJMP NB_W1

;-----------------------

N_B_Y:

CLR NB_G

NB_W2:

CJNE R4, #0, NB_DISP2

JMP D_X

NB_DISP2:

MOV A, R2

MOV C, ACC.3

MOV NB_Y, C

CALL DISPLAY

SJMP NB_W2

;***************************************

D_X:

MOV P3, #0 ;关闭全部红绿灯

SETB DX_G

SETB NB_R

MOV R3, #25

MOV R4, #20 ;东西通行时间

DX_W1:

CJNE R4, #0, DX_DISP

MOV R4, #5 ;东西黄灯时间

SJMP D_X_Y

DX_DISP:

CALL DISPLAY

SJMP DX_W1

;-----------------------

D_X_Y:

CLR DX_G

DX_W2:

CJNE R3, #255, DX_DISP2

JMP N_B

DX_DISP2:

MOV A, R2

MOV C, ACC.3

MOV DX_Y, C

CALL DISPLAY

SJMP DX_W2

;***************************************

DISPLAY:

MOV DPTR, #TAB1




MOV A, R3

MOV B, #10

DIV AB

MOVC A, @A + DPTR

MOV P0, A

MOV P2, #1

DJNZ R7, $

DJNZ R7, $

MOV P2, #0

;----------------------

MOV A, B

MOVC A, @A + DPTR

MOV P0, A

MOV P2, #2

DJNZ R7, $

DJNZ R7, $

MOV P2, #0

;----------------------

MOV A, R4

MOV B, #10

DIV AB

MOVC A, @A + DPTR

MOV P0, A

MOV P2, #4

DJNZ R7, $

DJNZ R7, $

MOV P2, #0

;----------------------

MOV A, B

MOVC A, @A + DPTR

MOV P0, A

MOV P2, #8

DJNZ R7, $

DJNZ R7, $

MOV P2, #0

RET




TAB1:

DB 0C0H, 0F9H, 0A4H, 0B0H, 99H

DB 92H, 82H, 0F8H, 80H, 90H

;***************************************




END

;-------------------------------------------




相关文章:
【最新修订版】555基于51单片机汇编语言设计的交通灯毕...
交通灯的控制 摘要: 本设计以 AT89C51 单片机为主控模块, 主要由按钮开关, 数码管, 发光二极管组成,利用汇编语言编写程序来模拟对十字路口的交通管理,系统 包括...
交通灯单片机汇编语言
本文档是智能交通灯的基于51单片机汇编语言,可在protues中仿真。本文档是智能交通灯的基于51单片机汇编语言,可在protues中仿真。隐藏>> ORG 0000H SJMP MAIN ...
基于单片机的交通灯的设计报告(汇编语言)
单片机 交通灯 汇编语言单片机 交通灯 汇编语言隐藏>> 交通灯的设计报告摘要: ...实现了能根据实际车流量通过 AT89C51 芯片的 P1 口设置红、绿灯熄亮时间 的...
usb单片机cs51交通灯程序汇编语言
51单片机设计交通灯(汇编语... 13页 免费喜欢此文档的还喜欢 ...这个参考程序使用汇编语言写的这个参考程序使用汇编语言写的隐藏>> ORG 0000H A...
基于51单片机做简易的交通灯
基于51单片机做简易的交通灯_信息与通信_工程科技_专业资料。目 录 摘要 ???...还有更深奥的知识,我将继续学习单片机及其编程语言,尽量去学 习汇编语言锻炼思维...
单片机proteus仿真设计交通灯(汇编语言)
单片机proteus仿真设计交通灯(汇编语言)_其它_高等教育_教育专区。51单片机,proteus...5.2 软件调试 主要是编程,以下是实现本次实验功能的程序: SECOND EQU 30H ...
基于51单片机的智能交通灯系统
基于51单片机的智能交通灯系统_信息与通信_工程科技_专业资料。基于51单片机的...(4)进行软件系统的设计,对于本系统,本人采用单片机汇编语言编写,对单片机 2 ...
基于单片机的交通灯的设计报告(程序为汇编语言)
基于单片机交通灯的设计报告(程序为汇编语言)_理学_高等教育_教育专区。需要硬件...实现了能根据实际车流量通过 AT89C51 芯片的 P1 口设置红、绿灯熄亮时间 的...
单片机交通灯程序(汇编语言)
单片机交通灯程序(汇编语言)_计算机软件及应用_IT/计算机_专业资料。用P0口的八个引脚控制交通灯闪烁 P1.0——1.2分别代表东西路口的红黄绿灯 P1.3——1.5...
汇编语言交通灯[1]
基于汇编语言的一种交通灯... 6页 免费 电源种类 2页 免费 关于单片机C语言...实现整个功能 调整完善整个硬件电路图让其美观 结束 三、选择的芯片: AT89C51...
更多相关标签: